# Some initial conditions
clear

# 1 second means 1 second
timerate rate 1

# makes the stars bigger
set star_scale 2.2

# let's go to Chicago
moveto lat 42
moveto lon -88

# Good starting date and time for Ursa Major
date utc 2006-07-15T03:15:00

# this flag will cause constellation names, etc, to only show for the constellation in which the star is selected.
# if a star that is not part of the line drawing is selected (and constellations are turned on) then all constellations
# are shown.
flag constellation_pick on

flag fog off
flag atmosphere off
flag landscape on
flag stars on
flag show_selected_object_info off

# Initially turn off constellations
flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### BIG DIPPER/URSA MAJOR
# Slew to the Big Dipper to start
flag cardinal_points off
select hp 53910 pointer off
zoom auto in
zoom fov 55

script action pause

flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### BIG and LITTLE DIPPERS
# Slew over a bit to show both big and little dipper to talk about pointer stars and North star
select hp 54935 pointer off
zoom auto in
zoom fov 55

script action pause

# Turn on the little bear
select hp 11767 pointer off
flag constellation_drawing on
flag constellation_names on
flag constellation_art on

script action pause

# zoom out a bit to show the direction is N
flag cardinal_points on
zoom fov 80 duration 2
wait duration 2

look delta_az 0.4
look delta_alt -0.2

script action pause

# Show that the North star really is always in the North.
# select the north star
select hp 11767 pointer off
zoom auto in
zoom fov 115

# Crank up the timerate a bit to show that the North star is always North
timerate rate 5000

# turn off the ground to make it easier to see
flag landscape off

# Now move ahead in time for a bit
wait duration 7

script action pause

# put things back
timerate rate 1
date utc 2006-07-15T03:15:00
flag landscape on

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### Scorpius
select hp 82396 pointer off
zoom auto in duration 3
zoom fov 35

script action pause

flag constellation_drawing on
flag constellation_names on
flag constellation_art on

wait duration 5

# select Antares to discuss meaning of its name, "not-Mars"
select hp 80763

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### Cygnus
select hp 100453 pointer off
zoom auto in duration 3
zoom fov 45 
set milky_way_intensity 1

script action pause

flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on

script action pause

#### Alberio
flag constellation_drawing off
flag constellation_names off
flag constellation_art off
set milky_way_intensity 0

select hp 95947 pointer off
zoom auto in duration 3
wait duration 3
zoom fov 0.25 duration 2
wait duration 2

script action pause

# zoom back out
zoom fov 45 duration 5
wait duration 5

flag constellation_drawing on
flag constellation_names on
flag constellation_art on

script action pause

#### LYRA ####
# After the zoom out, Lyra is well positioned.
# So select a star in Lyra to light it up
select hp 91262 pointer off

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### RING NEBULA
# While in the neighborhood let's look at the Ring Nebula
# Believe it or not, for some reason you have to use this phrase to find the M57.
select nebula "Ring nebula in Lyra" pointer off
zoom auto in
zoom fov 0.8 duration 5
wait duration 5

script action pause

# zoom back out
zoom fov 65 duration 5
wait duration 5

select hp 91262 pointer off

flag constellation_drawing on
flag constellation_names on
flag constellation_art on

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

wait duration 1

#### Pegasus and Andromeda
date relative 0.3
select hp 117332 pointer off
zoom auto in duration 3
zoom fov 60

script action pause

flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on


script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### M31 ####
select nebula m31 pointer off
zoom auto in duration 5

script action pause

# zoom back out to show where Andromeda is
zoom fov 60 duration 4
wait duration 4
select hp 117332 pointer off
zoom auto in duration 3
zoom fov 60

flag constellation_drawing on
flag constellation_names on
flag constellation_art on

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

wait duration 1

### Winter/Spring ####
date utc 2007-01-08T06:30:00

#### PLEIADES ####
# slide over to Pleiades to talk about how it is NOT the little dipper.
# But, need to back down the star_scale to see it better.
set star_scale 1.2
select hp 19388 pointer off
zoom auto in
zoom fov 20
script action pause

set star_scale 2.2


#### ORION ####
select hp 25336 pointer off
# These two zooms move over to the star and then sets the fov to be basically naked eye
zoom auto in duration 5
zoom fov 40

# pause the script - you press "6" to resume the script
script action pause 

# show lines, and names and then after 5 seconds show art
flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on

script action pause
flag constellation_drawing off
flag constellation_names off
flag constellation_art off

#### CANIS MAJOR ####
select hp 33977 pointer off
zoom auto in duration 2
zoom fov 40

# pause the script - you press "6" to resume the script
script action pause 

# show lines, and names and then after 5 seconds show art
flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on

script action pause

# Now zoom out a bit to show Canis Major and Orion and light up all constellations
select hp 29066 pointer off
zoom auto in duration 2
zoom fov 55

script action pause

flag constellation_drawing off
flag constellation_names off
flag constellation_art off

wait duration 1


#### Leo (and Saturn currently) ####
date utc 2007-1-26T05:30:00
# I don't want to tip off that Saturn is there.
flag planets off
select hp 46349 pointer off
zoom auto in
zoom fov 53

script action pause

flag constellation_drawing on
flag constellation_names on
wait duration 2
flag constellation_art on

script action pause

#### SATURN ####
# Now ask why there's that bright star in Leo that's not part of the constellation.
# Bright stars are always part of the constellation because they're so easy to see.
# So, let's zoom in and see what it is.
select planet Saturn pointer off
zoom auto in
wait duration 2
flag constellation_drawing off
flag constellation_names off
flag constellation_art off

script action pause

select hp 46349 pointer off
zoom auto in
zoom fov 53

flag constellation_drawing on
flag constellation_names on
flag constellation_art on


# Put some stuff back
flag show_selected_object_info on
flag constellation_pick off

# Always have this command at the end
script action end